Dowe

SERVER BLOCK / CRUD

Database-backed CRUD

A real endpoint graph, layered server modules, and a View form that reads, creates, updates, and deletes records.

LIVE VIEW + SERVER

Edit the example collection

AUTHENTICATEDGUEST

This page calls /api/examples/blogs. Use the Auth block first if you want to write data.

CREATE

Title

Content

Authenticate to enable writes.

UPDATE

Blog idNew title

New content

Records

Id	Title	Owner
No blogs yet Create the first record from the form above.

Delete uses the same authenticated session and the id from the table.

Delete by id

SOURCE FILES

Every tab is a real project file

The preview above calls the same handlers shown below. Database access remains in the repository, while Views only see JSON responses.

import exampleSession from "@/views/store/example-session"

page ServerCrudBlockPage
  signal blogs value:[]
  signal form value:{ title:"" content:"" }
  fn createBlog
    request result method:"POST" route:"/api/examples/blogs" body:form headers:{ Authorization:exampleSession.authorization }
    if result.ok
      set blogs value:result.data
      set form value:{ title:"" content:"" }
  Button onClick:createBlog show:exampleSession.authenticated
    "Create blog"

endpoints ApiRoutes
  group path:"/api/examples/blogs"
    get path:"" handler:listExampleBlogs
    post path:"" handler:createExampleBlog middleware:[requireExampleAuth]
    patch path:"/:id" handler:updateExampleBlog middleware:[requireExampleAuth]
    delete path:"/:id" handler:deleteExampleBlog middleware:[requireExampleAuth]

import createExampleBlogService from "@/server/services/example-crud-service"

handler createExampleBlog
  const body value:req.json
  createExampleBlogService result args:{ title:body.title content:body.content ownerId:req.context.auth.subject }
  return status:201 json:{ ok:true data:result.blogs created:result.created }

fn createExampleBlogService params:{ title:string content:string ownerId:string }
  createExampleBlogRepository created args:{ title:args.title content:args.content ownerId:args.ownerId }
  listExampleBlogsRepository blogs
  return value:{ created:created blogs:blogs }

fn createExampleBlogRepository params:{ title:string content:string ownerId:string }
  date now source:"now"
  query created conn:ExamplesDb.insert table:"example_blogs" value:{ title:args.title content:args.content ownerId:args.ownerId createdAt:now updatedAt:now } required:["title" "content" "ownerId"]
  return value:created

import ExampleBlogs from "@/server/entities/example-blogs-entity"

database ExamplesDb provider:"dowe" host:env.DOWE_HOST port:env.DOWE_PORT account:env.DOWE_ACCOUNT secret:env.DOWE_SECRET name:"dowe-docs-examples" entities:[ExampleBlogs] seeders:[]

entity ExampleBlogs
  id:string primary:true
  title:string required:true
  content:string required:true
  ownerId:string required:true index:true
  createdAt:timestamp required:true
  updatedAt:timestamp required:true

No blogs yet